Auflistung sämtlicher Formeln in gesondertem Tabellenblatt

[Excel-Axl]

Hallo,

ich habe eine Excel-Datei, die mehrere Tabellenblätter und einige hundert Formeln beinhaltet.

In einem gesonderten Tabellenblatt (z.B. "Formeldokumentation") sollen künftig sämtliche Formeln der Excel-Datei aufgelistet werden können. 

Z.B. in folgender Art:
Spalte A: Tabellenblatt (z.B. "Tabelle1")
Spalte B: Zelle (z.B. C7)
Spalte C: Formel

Wie kann ich dieses mittels eines Makros lösen?
Gibt es auch eine Alternative zu einem Makro und wenn ja, wie müsste die aufgebaut werden?

Am schönsten wäre es, wenn das Makro oder whatever jedes Tabellenblatt Zeile für Zeile nach Formeln durchsuchen würde, wäre aber letztlich egal...

Da ich leider keine Makro-Erfahrung habe, wäre es toll wenn eure Hinweise nicht zu verkürzt ausfallen... 

Vielen Dank im Voraus!

[gmg-cc]

Moin,

Füge diesen Code in das Modul "DieseArbeitsmappe" ein:

Code: [Auswählen]

Option Explicit

Sub AlleFormeln()
   Dim wksBlatt As Worksheet, wksFormeln As Worksheet
   Dim c As Range
   Dim BlName As String
   Dim fRow As Long
   
   Set wksFormeln = Sheets("Formeln")
   With wksFormeln
      .Cells(1, 1) = "Blatt-Name"
      .Cells(1, 2) = "Zell-Adresse"
      .Cells(1, 3) = "Formel"
   End With
   
   For Each wksBlatt In ActiveWorkbook.Sheets
      BlName = wksBlatt.Name
      If BlName <> "Formeln" Then
         For Each c In wksBlatt.UsedRange
            If c.HasFormula Then
               fRow = wksFormeln.Cells(Rows.Count, 1).End(xlUp).Row + 1
               With wksFormeln
                  .Cells(fRow, 1) = BlName
                  .Cells(fRow, 2) = c.Address(0, 0)
                  .Cells(fRow, 3) = "'" & CStr(c.Formula)
               End With
            End If
         Next c
      End If
   Next wksBlatt
End Sub

Da ich leider keine Makro-Erfahrung habe, wäre es toll wenn eure Hinweise nicht zu verkürzt ausfallen... 

habe ich gelesen. Aber wenn ich schon kostenlose Lösungen liefere, dann muss einfach noch eine "Reserve" für meine zahlenden Kunden bleiben. Da ist solch ein Code natürlich kommentiert und auch noch etwas "eleganter". 

Hinweis: Das Blatt, wo die Auswertung drin steht, MUSS den Namen "Formeln" (ohne Anführungen) haben, oder du änderst den Namen im Code.

EDIT: Code wegen eines Fehlers geändert

[Excel-Axl]

Hallo Günther,

WOW...  Vielen vielen Dank für das Makro!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! 


Viele Grüße
Mark

[medic]

interessantes Skript!
Bei mir kommt allerdings (unter 2003) folgendes raus:

Blatt-Name   Zell-Adresse   Formel Tabelle1   D2   =HLOOKUP(B2,$B$12:$F$13,2,FALSE)

wie kann ich die (mir gängigen) deutschen Formeln angeben lassen?

[gmg-cc]

… nicht nur unter 2003  Das sind nämlich die "wirklichen" Formeln. - Ändere den Code so ab:

Code: [Auswählen]

.Cells(fRow, 3) = "'" & CStr(c.Formula[color=red][b]Local[/b][/color])
und du hast die Ausgabe der Formeln in der auf dem Rechner installierten Sprache, vermutlich deutsch.