Spaltenkopf nach Auswerten in zus. Tabelle ausgeben

[SHeu112]

Hallo zusammen,
ich bin neu hier und hoffe, dass mir hier geholfen werden kann.
Folgende Tabelle (Bild) habe ich als Beispiel erstellt , um die nötige(n) Formel(n) verdeutlichen zu können.

Ich arbeite an einem Dienstplan, bei dem ich eine Übersicht in der Tabelle 1 habe mit den Namen der Kollegen als Spaltenkopf.
Darunter sind je Zeile (Schicht) nach Verwendung die Einteilung als Fahrer (Schrift rot) und Beifahrer (Schrift Schwarz).
Gibt es eine Funktion, die die unterschiedlichen Farben und Zahlen(Fahrzeugbesetzung) auswerten kann und dann den Namen in einer gesonderten Tabelle 2 darstellt?

Wenn das mit den Farben nicht geht, so bin ich für weitere Anrgeungen dankbar ( vielleicht 1A und 1B, falls das auswertbar ist)

Gruß und Danke
Stefan

[steve1da]

Hola,

ja, das geht. Solange die Nummern immer das gleiche repräsentieren (1=Fahrer, 2=Beifahrer, 3=Beifahrer), kann man zum einen die Färbung der Zahlen automatisieren. Zum Anderen kann man dann die Namen, die zu den Zahlen gehören ausgeben.

Eine kleine Beispieldatei die vom Aufbau her dem Original nahe kommt wäre toll.

Gruß,
steve1da

[SHeu112]

Hallo steve1da,
danke für Deine schnelle Antwort.
Im Anhang mal eine Tabelle mit meinen Vorstellungen.
Es können bis zu 50 Kollegen eingeteilt werden, d.h. es sollten auch Leerfelder möglich sein.
Als Schichten / Veranstaltungen / Zeilen können es auch bis zu 50 werden.
Auf der zweiten Seite möchte ich dann eine für jede Schicht geltende Auftstellung der Fahrzeugbesatzungen erhalten.
Wenn ich dann (dem Beispiel folgend) die Fahrzeugnummer als Suchfeld eingebe, sollte in der darauffolgenden Spalte der Fahrer (Schrift blau) und dann der Beifahrer (Schrift schwarz) auftauchen.

Ich selbst habs mal mit Index usw. versucht, bin dann aber gescheitrt. ;-(

Stefan

[steve1da]

Hola,

das wird wohl doch etwas aufwendiger als gedacht, da nicht nur immer die gleichen Zahlen eine bestimmte Farbe bekommen, sondern gleiche Zahlen auch unterschiedlich gefärbt werden (1 als Fahrer ist schwarz, 1 als Beifahrer ist blau).
Somit ist nicht automatisch erkennbar, welche 1 schwarz und welche blau sein soll.

Ich mach mir mal ein paar Gedanken darüber.

Gruß,
steve1da

[SHeu112]

Hallo steve1da,

nichts ist in Stein gemeißelt.
Wenn es einfacher ist, könnte ich auch, anstatt der Farben, fest zugeordnete Zahlen verwenden. (Das ist mir aber jetzt erst eingefallen). sry

Beispiel:
Fahrer 1 ist 11 (Fahrzeug 1 Position 1) und Beifahrer ist 12 (Fahrzeug 1 Position 2), Analog 21 und 22, usw. bis 101 und 102 bis 121 und 122
Oder auch 1A und 1B bis 12A und 12B... wenn das geht, ist es m.E. der beste Kompromiss

Gruß
Stefan

[steve1da]

Hola,

also ich hätte eine Möglichkeit, wenn die erste der beiden Zahlen immer der Fahrer ist, wenn also immer zuerst der Fahrer eingetragen wird. Die Färbung müsstest du zwar weiterhin selber vornehmen, aber dann würde in C2 folgende Formel kommen:

Code: [Auswählen]

{=INDEX(Übersicht!$1:$1;KKLEINSTE(WENN(Übersicht!$2:$2=$B2;SPALTE($1:$1));SPALTE(A1)))}
Achtung: die {} nicht mit eingeben, sondern die Formel mit Strg-Shift-Enter abschließen.

Das ist jetzt für Schicht 1, für Schicht 2 wäre die Formel:

Code: [Auswählen]

{=INDEX(Übersicht!$1:$1;KKLEINSTE(WENN(Übersicht!$3:$3=$B2;SPALTE($1:$1));SPALTE(A1)))}
usw.

Gruß,
steve1da

[SHeu112]

Hallo,

Danke für Deine Mühen, so ist mir schon mal geholfen, allerdings ist es so, dass ich dann die Fahrer immer in den Spalten tauschen müsste, da die Position Fahrer / Beifahrer auch wechselt.
Funktioniert die Formel denn nur mit Zahlen oder auch wie im anderen Thread erwähnt mit 1A und 1B, usw...?

Gruß

[steve1da]

Hola,

jepp, geht viel viel einfacher

Änder die Zahlen in 1a, 1b, 2a, 2b, 3a, 3b.....ab. Dann in C2:

Code: [Auswählen]

=WENNFEHLER(INDEX(Übersicht!$D$1:$U$1;VERGLEICH($B2&"a";Übersicht!$D$2:$U$2;0));"")
In D2:

Code: [Auswählen]

=WENNFEHLER(INDEX(Übersicht!$D$1:$U$1;VERGLEICH($B2&"b";Übersicht!$D$2:$U$2;0));"")
Beide Formeln nach unten kopieren.

Wenn du noch daran interessiert bist, bau ich dir auch eine Lösung für das automatische Färben wenn du Zahl+Buchstabe in die Zelle schreibst.

Gruß,
steve1da

[SHeu112]

Super, Klasse,
Dein Angebot in allen Ehren, aber ich will nicht zu gierig sein 

Da wäre ich nie drauf gekommen! Danke!

[steve1da]

Hola,

ach, das ist nur noch ne Kleinigkeit

Markier im Blatt Übersicht den Bereich der die Fahrerdaten enthält, also D2 bis irgendwas.

Start - Bedingte Formatierung - Neue Regel - Formel zur Ermittlung....

Code: [Auswählen]

=FINDEN("a";D2)
Unter "Formatieren" wählst du dann bei "Schrift" noch eine Farbe aus, die die Fahrer mit "a" hintendran erhalten sollen.

Gruß,
steve1da

[SHeu112]

Hallo steve1da,

Danke es klappt zumindest schon so, wie ich es mir vorgestellt habe.

In der neu angehängten Tabelle sind im  Übersicht mehrere Schichten angegeben.
Wenn ich mir jetzt einen speziellen Schichtplan anzeigen/ausdrucken möchte, muss ich diesen immer in Zeile 2 kopieren, wobei mir dann die Bezüge im Schichtplan  verloren gehen, da ich die vorherige Schicht/Zeile gelöscht habe.

Kann man Deine Formel so umbauen, dass ich, sobald ich die Schicht/Zeile im Schichtplan(Tabelle2) im  A1 aufrufe , zugleich die zugehörige Zeile in die Formeln bekomme?

Nachtrag: Schwierig ausgedrückt!
Bsp.: Wenn ich die Spalte B (Bezeichnung/Schicht)Zeile 10 aufrufe, dass dann auch die Zeile 10 durchsucht wird und ausgegeben wird,

Du siehst, dass ich zwei Funktionen noch angeben muss, dass ist der E-Dienst und der Zentralist, die in der Übersicht mit E und Z gekennzeichnet sind, ich bin leider zu unwissend, um die Suche nach E und Z umzustellen.

Gruß

[steve1da]

Hola,

zur ersten Frage: da muss dann erst gesucht werden, in welcher Zeile die Schicht steht:

B8:

Code: [Auswählen]

=WENNFEHLER(INDEX(Übersicht!$C$1:$U$1;VERGLEICH($A8&"a";INDIREKT("Übersicht!$C$"&VERGLEICH($A$1;Übersicht!$B$1:$B$7)&":$U$"&VERGLEICH($A$1;Übersicht!$B$1:$B$7));0));"")
C8:

Code: [Auswählen]

=WENNFEHLER(INDEX(Übersicht!$C$1:$U$1;VERGLEICH($A8&"b";INDIREKT("Übersicht!$C$"&VERGLEICH($A$1;Übersicht!$B$1:$B$7)&":$U$"&VERGLEICH($A$1;Übersicht!$B$1:$B$7));0));"")
Wieviele weitere Funktionen kommen denn noch dazu?

Gruß,
steve1da

[SHeu112]

Hallo steve1da,

sry ich habe nicht voll umfänglich die Funktionen durchdacht, und dann war ich auch noch der irrigen Annahme, selbst Deine Formel dahingehend umbauen zu können.

Ich werde den Thread jetzt schließen und Danke Dir nochmals für Deine Mühen!!!!

[steve1da]

Hola,

warum? Es gibt für fast alles eine Lösung

Gruß,
steve1da

[SHeu112]

Danke an steve1da!

Die Formel funktioniert mit allen Extrawürsten

Super, wäre ich nicht drauf gekommen!!

[steve1da]

Hola,

das mit E und Z muss noch verfeinert werden. Ich kann nicht ohne weiteres auf die Hintergrundfarbe abfragen, daher müsste wie bei den Zahlen ein eindeutiges Kennzeichen hinter E und Z damit man den Unterschied von Fahrer und Beifahrer ermitteln kann.

Gruß,
steve1da

[SHeu112]

OK, mal wieder unklar ausgedrückt.

Die Farbe ist bei E und Z immer schwarz, bzw. die Bezeichnung kommt nur einmal vor.
Kann ich ansonsten die Formel für "a" kopieren, wenn ich einfach Ea und Za in die Übersicht schreibe?

Gruß

[steve1da]

Hola,

sorry, da hab ich mich vertan.

B3:

Code: [Auswählen]

=WENNFEHLER(INDEX(Übersicht!$C$1:$U$1;VERGLEICH(LINKS(A3;1);INDIREKT("Übersicht!$C$"&VERGLEICH($A$1;Übersicht!$B$1:$B$7)&":$U$"&VERGLEICH($A$1;Übersicht!$B$1:$B$7));0));"")
B4:

Code: [Auswählen]

=WENNFEHLER(INDEX(Übersicht!$C$1:$U$1;VERGLEICH(LINKS(A4;1);INDIREKT("Übersicht!$C$"&VERGLEICH($A$1;Übersicht!$B$1:$B$7)&":$U$"&VERGLEICH($A$1;Übersicht!$B$1:$B$7));0));"")
Gruß,
steve1da

[SHeu112]

Danke, es klappt alles!!

Hut ab, steve1da!!

[SHeu112]

Hallo steve1da,

ich war ein wenig zu euphorisch, es klappt leider noch nicht so ganz mit meiner Anpassung der Formel.
In der angefügten Datei ist jetzt die Tabelle in Originalgröße (Zeilen und Spalten), so dass es vielleicht einfacher ist, die Formel anzupassen.
Irgendwie werden die zwar die Spalten, die ich mit einbezogen habe (bis BT) durchsucht und angezeigt, jedoch nicht mehr Zeilen, obwohl in den Formeln bis 41 geändert.
Desweiteren kann ich ausser "Schicht xy" keinen Freitext in der Bezeichnung (Übersicht Spalte B) eintragen und dann in Tabelle 2 B10 eintragen / anzeigen lassen.

Hoffe, Du hilfst mir nochmal

Gruß

[steve1da]

Hola,

ich verstehe dein Problem nicht.

Wenn ich im Blatt Übersicht verschiedene Schichten eintragen, werden diese auch angezeigt.

Und was du mit dem Freitext meinst ist mir auch völlig schleierhaft.

Gruß,
steve1da

[SHeu112]

Hola,

wenn ich die Datei bei mir auf dem Rechner öffne, werden nur noch die beiden ersten Schichten angezeigt, bei z.B. Schicht 5 und 6 (obwohl Daten vorhanden) bleibt die Tabelle 2 leer.
Bei Schicht 11 werden die Werte aus Schicht 1 angezeigt.

Office 10 und Windows 7.

Gruß

Nachtrag: Habe es gerade nochmal mit einer Kopie probiert, da klappte es zum Teil wieder, allerdings nicht, wenn ich anstatt Schicht xy zum Beispiel Montag eingebe und dann in Feld B10 in Tabelle 2 [Montag] schreibe, bleiben die Felder leer. Bei Änderung in Schicht xy werden diese angezeigt.

[steve1da]

Hola,

mein Fehler

B17:

Code: [Auswählen]

=WENNFEHLER(INDEX(Übersicht!$C$1:$BT$1;VERGLEICH(LINKS(A17;1);INDIREKT("Übersicht!$c$"&VERGLEICH($B$10;Übersicht!$B$1:$B$41;0)&":$bt$"&VERGLEICH($B$10;Übersicht!$B$1:$B$41;0));0));"")
B18;

Code: [Auswählen]

=WENNFEHLER(INDEX(Übersicht!$C$1:$BT$1;VERGLEICH(LINKS(A18;1);INDIREKT("Übersicht!$c$"&VERGLEICH($B$10;Übersicht!$B$1:$B$41;0)&":$bt$"&VERGLEICH($B$10;Übersicht!$B$1:$B$41;0));0));"")
B21:

Code: [Auswählen]

=WENNFEHLER(INDEX(Übersicht!$C$1:$BT$1;VERGLEICH($A21&"a";INDIREKT("Übersicht!$C$"&VERGLEICH($B$10;Übersicht!$B$1:$B$41;0)&":$BT$"&VERGLEICH($B$10;Übersicht!$B$1:$B$41;0));0));"")
C21:

Code: [Auswählen]

=WENNFEHLER(INDEX(Übersicht!$C$1:$BT$1;VERGLEICH($A21&"b";INDIREKT("Übersicht!$C$"&VERGLEICH($B$10;Übersicht!$B$1:$B$41;0)&":$bt$"&VERGLEICH($B$10;Übersicht!$B$1:$B$41;0));0));"")
Gruß,
steve1da

[SHeu112]

Kein Fehler!!!

Du hilfst mir, daher brauchst Du nicht von Fehler sprechen!!

Probiere es heute nachmittag mal aus, melde mich dann per PM

Gruß