Text einer Zelle nach Keywords durchsuchen und Kategorie zuordnen

[bertl123]

Hallo,

ich möchte gerne den Text der Zellen in Spalte A nach vorgegebenen Keywords durchsuchen. Wenn ein Keyword im Text gefunden wir, wird in Spalte B die zugehörige Kategorie ausgegeben.

Keywords sind in Spalte D und die zu dem jeweiligen Keyword zugehörige Kategorie in Spalte E.

Mit folgender Formel klappt es nur teilweise:

Code: [Auswählen]

=INDEX($E$2:$E$5,MAX(WENN(ISTFEHLER(SUCHEN($D$2:$D$5,A2)),-1,1)*ZEILE($D$2:$D$5)-1))
In D5 habe ich zwei Keywords und obige Formel erkennt diese nur im Text, wenn die beiden Wörter nicht durch anderweitigen Text getrennt sind. Ich suche eine Lösung, dass ich in zB. Zelle D5 die Keywords "Text1, Text3" stehen habe und mir die entsprechende Kategorie ausgegeben wird auch wenn beide Keywords getrennt voneinander im Text stehen. Ist das möglich oder bin ich da auf dem Holzweg?

Würde mich sehr über eine Hilfe freuen.

Ich habe mein Sheet beigefügt.


Viele Grüße

Ben



{maninweb: Bild etwas kleiner gemacht, da es sonst das Layout sprengt.}

[DL]

Hallo Ben

Schreibe die Keywords in zwei Spalten. Ich habe das mal in H:I gemacht; Spalte J ist die Kategorie.

Code: [Auswählen]

{=VERWEIS(42;1/(MMULT(WENNFEHLER(WENN(SUCHEN($H$2:$I$5;A2);1);0);{1;1})=2);$J$2:$J$5)}
Interessanterweise ist die Formel genauso lang wie deine bisherige Formel. 

[bertl123]

Hallo Detlef,

vielen Dank für Deine Hilfe.

Wenn ich die Formel einfügen will, zeigt es mir einen Fehler an. Ist die "42" korrekt?

Viele Grüße

Ben

Edit:
Jetzt hat es geklappt. Sensationell!! Vielen Dank. Ich musste bei mir nur die ";" durch "," ersetzten :-)

Viele Grüße

Ben

[bertl123]

Hallo Detlef,

noch eine kurze Frage.

Wenn nun keines der Keywords vorkommt, gibt mit die Verweisfunktion "#NV" aus.
Nun habe ich es mit "Wennfehler" versucht und wenn ich folgedes verwende, wird mir bei allen Zellen eine leere Ergebniszelle angezeigt:

Code: [Auswählen]

=WENNFEHLER(VERWEIS(42,1/(MMULT(WENNFEHLER(WENN(SUCHEN(Tabelle2!$S$2:$T$16,A15),1),0),{1;1})=2),Tabelle2!$Q$2:$Q$16),"")
Hast Du evtl einen Hinweis auf meinen Fehler?

Vielen Dank

Ben

[DL]

Die Formel ist weiterhin eine Matrixformel, die mit CTRL-SHIFT-ENTER eingegeben werden muss.

[bertl123]

Vielen Dank! Mir war zwar klar, dass ich CTRL+Shift+Enter verwenden muss, aber machte wohl einen Fehler.
Nun klappt es.

Vielen Dank für Deine schnelle Hilfe!!