Microsoft Office Forum [ www.Office-Fragen.de ] >> READONLY <<

Hallo Alle zusammen.

So hab mich gestern Abend mit einem Bekannten zusammen gesetzt um das Problem mit einen VBA Code zu Lösen.
Das funktioniert echt super.

Hier der VBA Code für die ihn brauchen könnten.

' Initale Generierung der Daten über die Komplette Tabelle
Sub init()
    Dim Zeile As Integer
    Zeile = 14
    While Cells(Zeile, 2) <> ""
        If Cells(Zeile, 6) <> "" Then
            Call splitData(Zeile)
        End If
        Zeile = Zeile + 1
    Wend
End Sub

' Aktualisierung der Daten bei änderung der Zelle
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Row > 6 And Target.Column = 6 Then
        For i = 0 To 8
            Cells(Target.Row, i + 7) = ""
        Next i
        Call splitData(Target.Row)
    End If
End Sub

' Daten aus Spalte 6/F der jeweiligen Zeile auslesen
' Zerlegen und die die weiteren Spalten eintragen
Sub splitData(Zeilennummer As Integer)
    Dim line As String
    Dim WrdArray() As String
    Dim WrdArray2() As String
    Dim StaArray
    Dim EndArray
   
    ' Zelle einlesen
    line = Cells(Zeilennummer, 6).Value
   
    ' Zerlegen mit Teiler //
    WrdArray() = Split(line, "//")
   
    ' wenn 9 Teile gefunden wurden
    If UBound(WrdArray) = 8 Then
       
        ' Über die 9 Teile drüber gehen
        For i = 0 To 8
        ' Falls ein Fehler passiert (bei umwandlung in Zahl) diesen einen Teil überspringen
        On Error GoTo Fehler
       
            ' Versuchen den Teil nochmal mit Teiler : zu zerlegen
            WrdArray2() = Split(WrdArray(i), ":")
           
            ' Wenn das geklappt hat und 2 weitere Teilen entstanden sind
            If UBound(WrdArray2) = 1 And i <> 5 Then
                ' den 2. Teil in die jeweilige Zelle eintragen
                Cells(Zeilennummer, i + 7) = Trim(WrdArray2(1))
            ' ausser es handelt sich um die 6. Spalte (Strom)
            ElseIf UBound(WrdArray2) = 1 And i = 5 Then
                l = Len(Trim(WrdArray2(1)))
                ' dann noch das A wegschneiden
                Cells(Zeilennummer, i + 7) = CDbl(Left(Trim(WrdArray2(1)), l - 2))
            ' konnte nicht geteilt werden alles in die Zelle eintragen
            Else
                Cells(Zeilennummer, i + 7) = WrdArray(i)
            End If
Fehler:
        Next i
    End If
End Sub

MFG

Christoph

Daten einer Zelle auf mehrere aufteilen Automatisch.

Hallo

Bin neu in diesem Forum da ich Hilfe brauch bei einer Excel Funktion bzw. wie man mein Problem am besten Lösen könnte.

Es geht darum das ich in einer Zelle sehr viele Daten habe, die Ich auf mehrere Zellen aufteilen möchte.
Da ich aber nicht so der Excel Profi bin habe ich es derzeit etwas kompliziert gelöst.
mit den Funktionen Links, Rechts, Teil.

Die Daten sind nicht immer gleich strukturiert bzw. verschieden lang.

Hawker Sidley // Frame : MW - 400 //Freq. :50 //RPM : 589 //Volt. : 380 // Rated Current : 470.6 A // Cos phi : ?? // IP : ?? // KW :250
WEG // Frame : 250 //Freq. :50 //RPM : 1480 //Volt. : 380 // Rated Current : 142 A // Cos phi : ?? // IP : 65 // KW :75

das sind zwei verschiedene Zellen jeweils in Spalte F ich möchte jetzt die Daten so auf teilen:Spalte
G= Hersteller (Hawker Sidley oder WEG) ; H=Frame ; I=Freq. ; J=RPM ; K=Volt ; L= Rated Current ; M=Cos phi; N=IP ; O=KW ;

Bitte um Hilfe da es sehr mühselig ist die Daten mit meinen bereits erstellten Formeln aufzuteilen.

Für Spalte G habe ich derzeit die Formel =LINKS(F12;SUCHEN("/";F12)-1) die funktioniert eigentlich ganz gut.
Für Spalte H-N habe ich derzeit die Formel =TEIL(F12;45;2) da aber der Text sehr variiert muss ich immer die Zahl beim erste Zeichen ändern das ist sehr viel Arbeit bei über 600 Zeilen.
Für Spalte O habe ich derzeit die Formel =RECHTS(F12;4)
 

BMM // Frame : ?? //Freq. :50 //RPM : 1450 //Volt. : 380 // Rated Current : 37 A // Cos phi : ?? // IP : ?? // KW :18.5
SEW-EURODRIVE // Frame : ?? //Freq. :50 //RPM : 1400 //Volt. : 380 // Rated Current : 8.6 A // Cos phi : 0.83 // IP : ?? // KW :2.2
Kleines bespiel wie es aussehen sollte.

Spalte F=WEG // Frame : 250 //Freq. :50 //RPM : 1480 //Volt. : 380 // Rated Current : 142 A // Cos phi : ?? // IP : 65 // KW :75
Spalte G=WEG (manchmal 2 Zeichen und bis hin zu 7 Zeichen lang)
Spalte H=250 (manchmal 2 Zeichen und bis hin zu 7 Zeichen lang)
Spalte I=50 (immer 2 Zeichen lang nur dadurch das die ersten zwei immer verschieden lang sind variiert die Position sehr ca. zwischen 2 und 20 Zeichen)
Spalte J=1480 (manchmal 2 Zeichen und bis hin zu 4 Zeichen lang)
Spalte K=380 (immer 3 Zeichen lang nur dadurch das die vorderen immer verschieden lang sind variiert die Position sehr ca. zwischen 2 und 20 Zeichen)
Spalte L=142 (manchmal 2 Zeichen und bis hin zu 4 Zeichen lang)
Spalte M=?? (manchmal 2 Zeichen und bis hin zu 4 Zeichen lang)
Spalte M=65 (manchmal 2 Zeichen und bis hin zu 4 Zeichen lang)




Danke schon mal im voraus.

Es ist egal ob es mit Formel oder mit VBA Skript Funktionieren würde.

MFG
Christoph