Menü
An- und Abmelden
Partner / Links
Beiträge anzeigen
1
Excel / Antw: Makro: Datum Zelle mit bestimmten Inhalt gefüllt wird
« am: Juni 03, 2016, 14:16:21 Nachmittag »
Hallo,
anstatt einen Bereich zu durchsuchen kannst du auch sofort nach einer Änderung die jeweilige Zelle prüfen:
Kommst du damit weiter?
Gruß
Melanie
anstatt einen Bereich zu durchsuchen kannst du auch sofort nach einer Änderung die jeweilige Zelle prüfen:
Code: [Auswählen]
Private Sub Worksheet_Change(ByVal Target As Range)
Dim strColCheck As String
Dim strColDate As String
Dim strText1 As String
Dim strText2 As String
' Änderung von 1 Zelle überwachen
If Target.Count > 1 Then Exit Sub
' Spalte die geprüft werden soll
strColCheck = "Q"
' Spalte für Datum
strColDate = "AT"
' zu prüfender Text
strText1 = "Installed"
strText2 = "Cancelled"
' ist geänderte Zelle in angegebener Spalte?
If Not Application.Intersect(Target, Columns(strColCheck)) Is Nothing Then
Application.EnableEvents = False
' Zellwert prüfen
Select Case Target.Value
Case strText1, strText2
With Cells(Target.Row, strColDate)
.Value = Date
.NumberFormat = "YYYY-MM-DD"
End With
Case Else
' altes Datum löschen
Cells(Target.Row, strColDate).ClearContents
End Select
Application.EnableEvents = True
Exit Sub
End If
' 2. Bereich prüfen
strColCheck = "A"
strColDate = "AQ"
' ist geänderte Zelle in angegebener Spalte?
If Not Application.Intersect(Target, Columns(strColCheck)) Is Nothing Then
Application.EnableEvents = False
' Zellwert prüfen
If Target.Value <> "" Then
Cells(Target.Row, strColDate).Value = Date
Else
' altes Datum löschen
Cells(Target.Row, strColDate).ClearContents
End If
Application.EnableEvents = True
End If
End Sub
Kommst du damit weiter?
Gruß
Melanie