Besucherliste auswerten - Datum bestimmten Monat zuordnen und summieren

[jott]

Hallo ihr Lieben,

nach bereits erfolgsloser Suche und Recherche nach einer Lösung für mein Problem, wende ich mich hilfesuchend an euch.

Folgendes:
Ich werte gerade eine ganzjährige Besucherliste mit über 3000 Gästen aus. Ziel der Auswertung ist es, zu erkennen wie oft ein Gast im Monat da war und wie häufig insgesamt im Jahr. Nun möchte ich die Besucher (mehrere gleiche Besucher in einem Jahr) addieren und das Besucherdatum automatisch dem entsprechenden Monat zuweisen.
Welche Funktion kann ich hier anwenden? Wenn-Funktion oder "Zelle zuordnen", vielleicht sogar eine ganz andere?
Habt ihr eventuell eine bessere Idee, wie ich die Tabelle aufstellen sollte? :-)

Damit ihr einen besseren Überblick bekommt, habe ich einen Screenshot von meiner Tabelle gemacht.

Ich freue mich über jeden Ratschlag und wäre über eure Hilfe sehr dankbar! 

Greetings! jott

[steve1da]

Hola,

hier wäre eine Beispieltabelle sinnvoll, damit man sieht, in welchem Format die Daten vorliegen.

Gruß,
steve1da

[jott]

Habe ich dich so richtig verstanden? 

[steve1da]

Hola,

eigentlich eher eine xlsx Datei

Gruß,
steve1da

[jott]

Sorry!

Hier als Excel-Datei

[steve1da]

Hola,

Code: [Auswählen]

=SUMMENPRODUKT((MONAT($C$2:$C$31)=SPALTE(A1))*($C$2:$C$31<>"")*($A$2:$A$31=$A2)*($B$2:$B$31=$B2))
kommt natürlich über all 0 raus, sind ja auch keine Daten in Spalte C.

Gruß,
steve1da

[jott]

Ach man, ich kann irgendwie nicht mehr klar denken 

Hier nochmal aktualisiert.
Ich probiere es mal eben aus :-)

LG jott

[jott]

Woooow, ich bin total begeistert!!!!   

Hast du eine Idee, wie man die Gesamtsumme am Ende noch summieren kann?

Liebe Grüße, jott

[steve1da]

Hola,

meinst du?

Code: [Auswählen]

=SUMME(D2:O2)
Gruß,
steve1da

[jott]

Nicht ganz, ich dachte daran, diese Formel mit in die Andere zu integrieren.

Aber das ist sicherlich zu kompliziert oder? 

Greetings,
jott

[steve1da]

Hola,

ich kann mnir momentan nicht ganz vorstellen, was du vorhast.

Wie sähe denn dein Wunschergebnis aus?

Gruß,
steve1da

[jott]

Ich füge dir mal meine bearbeitete Beispieltabelle bei.

Jetzt werden die Daten richtig angezeigt, doch sie wiederholen sich logischerweise bei den mehrmaligen Besuchern. Macht es hier sinn, die Zeilen einfach auszublenden oder gibt es einen Trick für Duplikate "ausblenden"?
Entfernen kann ich sie ja nicht, weil sonst die Bezüge verloren gehen.

Anschließend könnte ich dann eine Gesamtsumme, sprich der Formel =SUMME(D2:O2) ziehen.
Ist es möglich die Gesamtsumme in die =SUMMENPRODUKT((MONAT($C$2:$C$3423)=SPALTE(A1))*($C$2:$C$3423<>"")*($A$2:$A$3423=$A2)*($B$2:$B$3423=$B2)) zu integrieren?

Greetings,
jott

[steve1da]

Hola,

ich werde wohl erst morgen dazu kommen, die neue Datei anzuschauen, daher frage ich jetzt mal "blind" nach

Wäre es eine Option die jetzige Liste der Namen und Vornamen und Daten in eine zweite Liste umzuwandeln, automatisiert natürlich, die die Namen ohne Doppelte beinhaltet? Der Rest der Auswertung könnte dann so bleiben, also die Monatsanzeigen und Summen. Es wird halt nur die Tabelle ohne Doppler erzeugt.

Wenn ja, dann bau ich dir das morgen früh. Vielleicht klärt sich dann auch für mich, was du mit der Integration der Summe meinst

Gruß,
steve1da

[jott]

Ja, das wäre natürlich die beste Option. 

Magst du mir verraten, wie ich die zweite Liste erstellen kann?
Falls ich dich unterstützen kann, würde ich das schon mal für morgen vorbereiten.

Meine Datei ist riesengroß und deshalb natürlich auch nicht einfach zu verschicken.

Greetings,
jott

[steve1da]

Hola,

ich würde das hieraus basteln:

http://www.excelformeln.de/formeln.html?welcher=194

Die Riesendatei braucht es wohl nicht - es geht ja nur um die Liste der Namen ohne Duplikate, das kriegen wir dann schon auf dein Orginial angepasst

Gruß,
steve1da

[jott]

Wow, danke für deinen Einsatz!
You made may day!

Wie kommen wir morgen zusammen?

Greetings,
jott

[steve1da]

Hola,

also, ich habe mir deine Liste aus Tabelle 1 in Tabelle 2 kopiert und dort die Spalte C entfernt (In C1 steht jetzt also "Jan"). Tabelle 1 dient also nur als Quelle.
In Tabelle 1 in R2 habe ich folgende Formel:

Code: [Auswählen]

=A2&B2
Die ziehst du nach unten. In Tabelle2 in T2 habe ich:

Code: [Auswählen]

=Tabelle1!R2
In T3 zum runterziehen:

Code: [Auswählen]

{=WENNFEHLER(INDEX(Tabelle1!$R$2:$R$31;VERGLEICH(1;(ZÄHLENWENN(T$2:T2;Tabelle1!$R$2:$R$31)=0)*(Tabelle1!$R$2:$R$31<>"");0));"")}
Achtung! Die {} nicht mit eingeben, sondern die Formel mit Strg-Shift-Enter abschließen!

In Tabelle 2 A2 dann folgende Formel zum nach rechts und nach unten ziehen (für Name und Vorname):

Code: [Auswählen]

=WENNFEHLER(INDEX(Tabelle1!A$2:A$31;VERGLEICH($T2;Tabelle1!$R$2:$R$31;0));"")
In Tabelle 2, C2 kommt dann die schon bekannte Summenprodukt-Formel, allerdings jetzt mit Bezug auf Tabelle 1:

Code: [Auswählen]

=SUMMENPRODUKT((MONAT(Tabelle1!$C$2:$C$31)=SPALTE(A1))*(Tabelle1!$C$2:$C$31<>"")*(Tabelle1!$A$2:$A$31=$A2)*(Tabelle1!$B$2:$B$31=$B2))
Gruß,
steve1da

[jott]

Hola,

folgendes Problem ergibt sich bei mir, nach dem Einsetzen dieser Formel:
{=WENNFEHLER(INDEX(Tabelle1!$R$2:$R$31;VERGLEICH(1;(ZÄHLENWENN(T$2:T2;Tabelle1!$R$2:$R$31)=0)*(Tabelle1!$R$2:$R$31<>"");0));"")}

Nach Einsetzen und Runterziehen in die folgenden Zellen, wird der Name nicht übernommen sprich "Joel Alvarx" bleibt stehen.
Habe in der Formel nachgesehen, aber finde den Fehler leider nicht. :-(
Magst du mal nachsehen, was hier nicht stimmt?

Liebe Grüße,
jott

[steve1da]

Hola,

hatte ich vergessen zu erwähnen - du musst auf beiden Blättern alle Zeilen einblenden. Erst dann die Formeln setzen.

Gruß,
steve1da

[jott]

Moin,

hat alles super geklappt!
Danke für deine Mühe, das hat mir sehr geholfen! 

Greetings,
jott