Office 2007: Sverweis, Summewenn oder ganz was anderes???

[Hennes]

Hallo zusammen,

ich muss einen Preisrechner basteln, und komme mit meiner Formel nicht weiter bzw wirft mir meine Formel keinen Preis raus. Was ist falsch??? Kann mir jemand helfen???

zur Erläuterung:
es gibt drei Bedingungen: Tag (Montag bis Sonntag), Zeitraum (Zeit von - bis) und ob das angegebene Datum ein Feiertag ist.

Gruß Hennes

[DL]

Hallo Hennes

B2

Code: [Auswählen]

=TEXT(B1;"TTTT")B3

Code: [Auswählen]

=ZÄHLENWENN('Feiertage NRW'!$A$1:$A$34;B1)B6

Code: [Auswählen]

=INDEX(Preismatrix!$B$2:$I$31;VERGLEICH(B4;Preismatrix!$A$2:$A$31;1);VERGLEICH(B2;Preismatrix!$B$1:$I$1;0))
Was die Feiertage in der Preismatrix bewirken sollen ist mir nicht klar.

[Hennes]

Hallo Detlef,

schonmal vielen Dank dafür.
Werde es gleich mal testen.
Feiertage sind ja nicht immer am Wochenende.
Wenn also ein Feiertag zwischen Montag und Freitag ist, gilt nicht der Preis von Montag bis Freitag sondern eben der Feiertagspreis.

Gruß Hennes

[Hennes]

Hallo Detlef,

sieht schonmal ganz gut aus. Jedoch müsste der Preis in diesem Beispiel
23,- € betragen, Also für die jeweils halben Stunden zwischen 16:00 und 17:30...
16:00 bis 16:30 = 7,-
16:30 bis 17:00 = 7,-
17:00 bis 17:30 = 9,-
Summe               = 23,-

Daher dachte ich an ein Summewenn-Formel.

Gruß Hennes

[DL]

Hallo Hennes

Die Spalte Feiertag habe ich jetzt erst entdeckt.
Und summieren war mir vorher auch nicht klar.
B2

Code: [Auswählen]

=WENN(ZÄHLENWENN('Feiertage NRW'!$A$1:$A$34;B1);"Feiertag";TEXT(B1;"TTTT"))B3

Code: [Auswählen]

Keine FormelB6

Code: [Auswählen]

=SUMMENPRODUKT(INDEX(Preismatrix!B2:I31;0;
VERGLEICH(B2;Preismatrix!B1:I1;0))*
(TEXT(Preismatrix!A2:A31;"hh:mm")>=TEXT(B4;"hh:mm"))*
(TEXT(Preismatrix!A2:A31;"hh:mm")<TEXT(B5;"hh:mm")))

[Hennes]

Hallo Detlef,

hab ich vielleicht auch nicht so deutlich rüber gebracht, sorry.
ABER, jetzt funktioniert es bestens.!!!
Vielen Dank.

Gruß Hennes

[Hennes]

Hallo nochmal zusammen,

das Thema ist eigentlich abgeschlossen. Alles funktioniert bestens.
Dank nochmal an Detlef.
Ich weiß, das hier ist ein Excel Forum. Aber hat jemand eventuell eine Idee, wie ich diesen Rechner in ein Widget umwandeln kann???

Gruß Hennes