vorherigen Wert nach Kriterium suchen

[fred-neumann]

Nun wird`s für mich mal so richtig deftig;
Ich suche nach Kriterium den entsprechenden vorherigen Wert.
Kriterium: jeweils der Verein in Spalte A
Wert: jeweils in Spalte E

"Wunschergebnis" stellt das gewünschte Ergebnis dar,- aber wie lautet die Formel?

Ich habe ein Arbeitsblatt angehängt,- verdeutlicht meine Anfrage

[Fred0]

Hallo

ein bißchen dünn deine Angaben/Frage hier und eine zip-Datei lädt auch nicht jeder runter.
Erkläre bitte genauer was du gerne möchtest.

[fred-neumann]

Hallo Fred0,
.. ist  (für mich) wirklich bischen komplex dies zu erklären, habe mal ein bild vom Beispiel hochgeladen.

Ich ermittel in "mw HeimTore" den Mittelwert der Teams in Spalte A
Nun suche ich für jedes Team1 nicht den "aktuellen Mittelwert", sondern den zuvor ermittelten. Wenn es keinen zuvor gibt, dann 0
und das gewünschte Ergebnis liegt in Spalte F vor --- aber wie lautet die Formel ?

[DL]

Hallo Fred

Die Formel in Spalte E geht auch anders:

Code: [Auswählen]

=MITTELWERTWENNS(C$2:C2;A$2:A2;A2)
Für Spalte F:

Code: [Auswählen]

=WENNFEHLER(VERWEIS(42;1/(A$1:A1=A2);E$1:E1);0)

[fred-neumann]

Jo, DL - so mach ich`s
___________________________
Langsam werd ich vor lauter Formeln, Zahlen link-rechts panne.
Ich möchte aber gerne noch einen Wert ermitteln, folgendes;
Ich habe HeimTeam ; GastTeam ; Heimtor ; Gasttor
Was ich ermitteln möchte:
Ich möchte gerne aus Sicht des Heimteams ermitteln, wie oft es in den letzten 2 beteiligten Spielen zu Null gespielt hat. Egal ob 0 Treffer oder 0 Gegentreffer, Egal ob Heim,- oder Auswärts.
Ich habe mal ein erklärendes Abeitsblatt angefügt, vieleicht bekomme ich eine Lösung ohne "Hilfsspalte".

[DL]

Hallo Fred

Hifsspalte M:

Code: [Auswählen]

=VERWEIS(42;1/(B$1:B1=B2);ZEILE(B$1:B1))Ergebnisspalte N:

Code: [Auswählen]

=WENNFEHLER(SUMMENPRODUKT((INDEX(B$1:B2;L2):B2=B2)*(MMULT(--(INDEX(D$1:E2;L2;0):E2=0);{1;2})>0));88)

[fred-neumann]

Hallo Detlef,
Danke für deine Aufmerksamkeit und Mühe!
In Spalte N mußte die Formel mit den Bezug auf Spalte M entsprechend angepasst werden

Code: [Auswählen]

=WENNFEHLER(SUMMENPRODUKT((INDEX(B$1:B2;M2):B2=B2)*(MMULT(--(INDEX(D$1:E2;M2;0):E2=0);{1;2})>0));88)
.. ist aber kein Thema.

In Spalte M soll wohl der Verweis() die vorherige Anzahl der Spiele vom Gastteam wiedergeben.
Ab Zeile 8 (Leverkusen : Hannover) wird ein falscher Wert zurück gegeben.
Und das Endergebnis in Spalte N stimmt dementsprechend leider auch nicht ...

DL, kannste bitte noch mal drauf schaun und den Fehler suchen.
Gesucht wird nach wie vor;
Die 2 vorherigen Spiele eines Heimteams mit einem "0 Ergebnis".
Egal ob das Heimteam zuvor Heim,- oder Auswärts antrat, egal ob 0 Treffer oder 0 Gegentreffer ( zB 1:0, 0:2 usw.)

ist schon recht kompliziert!

[fred-neumann]

Es geht ja um das ermitteln der 2 vorherigen Spiele, ob dort "zu Null" gespielt wurde und wie oft.
Vieleicht ist es hilfreich, wenn eine Hilfsspalte eingesetzt wird, die ermittelt, ob im Spielergebnis ein "zu Null" vorhanden ist. Ich habe das Arbeitsblatt entsprechend geändert nochmal beigefügt. Vieleicht gibt es so die korekte Lösung.

[steve1da]

Hola,

zur Info...

http://www.herber.de/forum/messages/1473834.html

Gruß,
steve1da

[fred-neumann]

danke steve1da,
ich werde aber trotzdem bei Lösung nochmals drauf hinweisen.
Hoffe, das ich gegen keine Foren-Regel verstoßen habe!

[fred-neumann]

Es ist geschafft !!
Dank http://www.herber.de/forum/messages/1473863.html und kompetenter Hilfe von Mitglied Werner ist die Formel gefunden.

Die von Werner erstellte Matrixfunktionsformel lautet:

Code: [Auswählen]

=WENNFEHLER(INDEX(L:L;AGGREGAT(14;6;ZEILE(A1:A$2)/(MMULT(ZÄHLENWENN(B2;B1:C$2); {1;1})>0); 1))+INDEX(L:L;AGGREGAT(14;6;ZEILE(A1:A$2)/(MMULT(ZÄHLENWENN(B2;B1:C$2); {1;1})>0); 2)); 88)
Sie ermittelt jeweils für das HeimTeam die vorherigen 2 Spiele und stellt fest, ob und wie oft "zu Null" gespielt wurde. Gibt es keine vorherigen 2 Spiele, wird 88 angezeigt.
Ich bedanke mich bei Excel-Guru Werner und sehe dieses Thema geschlossen.
Ein Arbeitsblatt mit der Formel ist beigefügt