Office 2010: Richtige (automatische) Zuordnung von Werten in einer 2. Tabelle

[Mike48]

Liebes Forum,

ich stehe noch ziemlich am Anfang meiner Excel-Erfahrungen, soll aber bis Montag folgende Aufgabe lösen:

Wir haben z.B. zwei Tabellen, die aussehen wie im Anhang:

In Spalte j werden die Werte aus Spalte x automatisch nach Größe geordnet. Jetzt soll dem jeweiligen Wert, der in der Spalte j steht, der dazugehörende Wert aus Spalte z zugeordnet werden (also neben die 9 in j soll AUTOMATISCH weil c in k übertragen werden, so dass die zwei zusammengehörenden Werte von x und z in j und k zusammenbleiben. (Dieser Vorgang wurde hier manuell ausgeführt.) Zahlen, die mehrfach vorkommen, muss in k jedesmal der Reihe nach der dazugehörende Wert zugeordnet werden, also wie im Beispiel der 9 zuerst der Wert weil c und dann der Wert weil g.

In den Spalten x und j stehen immer Zahlen, in z und k immer Wörter.

Ich weiß nicht, ob das verständlich rüberkommt. Hat jemand einen Lösungsvorschlag? Vielen Dank! Mike

Tabelle:

x   z                  j           k
3   weil a         9   weil c
4   weil b         9   weil g
9   weil c         6   weil d
6   weil d         5   weil f
3   weil e         4   weil b
5   weil f         3   weil a
9   weil g         3   weil e

[steve1da]

Hola,

Code: [Auswählen]

=INDEX($B$2:$B$8;AGGREGAT(15;6;ZEILE($A$2:$A$8)-1/($A$2:$A$8=E2);ZÄHLENWENN($E$2:E2;E2)))
Gruß,
steve1da

[Mike48]

Danke für die schnelle Antwort steve1da. Ich probiere aus.

Gruß Mike48

[Mike48]

Hallo,
habe heute den Lösungsvorschlag ausprobiert, der aber leider nicht geklappt hat. Vielleicht habe ich das Problem bem ersten Mal nicht richtig beschrieben. Im Anhang schicke ich daher die Tabellen mit, die ich tatsächlich bearbeiten soll. Hat jemand einen Lösungsvorschlag?

Die Aufgabe lautet:
Es sollen lediglich die Tabellen "Gefährdungsbeurteilung" und "5 Hauptrisiken" betrachtet werden und dabei bei der Gefährdungsbeurteilung nur die Spalten A und E (Gefährdungsart und Risiko) und bei den  5 Hauptrisiken nur J und K (Gefährdungsart und Risikogröße). Alle anderen Einträge, Farben usw. spielen keine Rolle.
Aus der Tabelle Gefährdungsbeurteilung sollen nun die 5 Einträge mit der höchsten Zahl unter Risiko zusammen mit der jeweiligen Gefährdungsart in die Tabelle 5 Hauptrisiken übertragen werden.

Ich habe jetzt nochmal rumprobiert und die Spalte J in der Tabelle "5 Hauptrisiken" mit folgender Formel definiert:

=INDEX($Gefährdungsbeurteilung.A7:A14;VERGLEICH(K7;$Gefährdungsbeurteilung.E7:E14;0))

Das Problem ist, dass unter Anwendung dieser Formel bei gleicher Risikogröße (in diesem Fall 20) auch jeweils die gleiche Gefährdungsart übernommen wurde, was natürlich nicht Sinn der Sache ist. In die Spalte J neben der zweiten 20 hätte die Gefährdungsart "Gefahrstoffe" übertragen werden sollen. Wo könnte der Fehler liegen?

Danke für eure Hilfe,

Mike

[steve1da]

Hola,

ich hatte dir eine Formel aufgezeigt, mit der man das schön abfragen kann - leider kann ich die nirgends finden. Und warum kommt der genau Aufbau/die genaue Frage nicht schon im Eingangspost?
In K7 zum runterziehen:

Code: [Auswählen]

=KGRÖSSTE(Gefährdungsbeurteilung!$E$7:$E$14;ZEILE(A1))
Für die Gefährdungsart dann:

Code: [Auswählen]

=INDEX(Gefährdungsbeurteilung!$A$7:$A$14;AGGREGAT(15;6;ZEILE($A$7:$A$14)-6/(Gefährdungsbeurteilung!$E$7:$E$14='5 Hauptrisiken'!K7);ZÄHLENWENN($K$7:K7;K7)))
Gruß,
steve1da

[Mike48]

Hallo steve1da,

danke für deine schnelle Antwort und den Lösungsvorschlag. Die Formel, die du erwähnt hast, ist bei mir nicht angekommen, sondern nur der Code im Text deiner ersten Antwort. Den Grund dafür weiß ich nicht.
Du hast recht, den genauen Aufbau/ die genaue Frage hätte ich gleich im Eingangspost schicken sollen. Meine Idee war halt, das Problem möglichst einfach zu beschreiben.
Ich bin ziemlich beeindruckt, wie schnell du eine Lösung dafür gefunden hast. Ich habe Stunden darüber gegrübelt. Danke nochmal!
Gruß,
Mike48